Доброго времени суток!

В данной статье я попытаюсь рассказать Вам о том, как при помощи простой, но достаточно мощной утилиты Log Parser осуществлять парсинг файлов, используя объектную COM-модель IS-Builder. Многие из Вас, наверно, уже знакомы с утилитой Log Parser, а для тех, кто не знаком с ней, я опишу ее назначение в разделе "Немного о Log Parser".

Немного о Log Parser

Log Parser – это многофункциональное и универсальное средство, которое предоставляет универсальный доступ по запросу к таким текстовым данным, как файлы журнала, XML- и CSV-файлы, а также к основным источникам данных в операционной системе Windows, например журналу событий, реестру, файловой системе и службе каталогов Active Directory.  Для работы с Log Parser необходимо указать требуемый источник данных и способ их обработки. Результаты запроса можно представить в пользовательском текстовом формате вывода или в более специализированных форматах, например SQL, SYSLOG или в виде диаграммы.

IS-Builder и Log Parser

Для осуществления работы с Log Parser необходимо произвести создание COM-объекта LogQuery:

LogQuery = CreateObject('MSUtil.LogQuery')

Следующим шагом следует определить формат входного файла:

InputFormat = CreateObject(ProgID)

Таблица соответствия входного формата и ProdID приведена ниже:

Необходимо учесть, что ProgID должен быть передан в виде строки. Например, для парсинга файлов формата CSV, необходимо произвести создание следующего COM-объекта:

InputFormat = CreateObject('MSUtil.LogQuery.CSVInputFormat')

После того, как задан входной формат необходимо составить SQL-запрос. Например:

PATH = 'D:\Table1.csv'
SQL = Format(‘SELECT * FROM %s’; PATH)

Данный запрос произведет выборку всех записей из файла. Но не всегда выборка содержит только те столбцы, которые указаны в файле. Например, при парсинге файлов формата CSV данным запросом, первый столбец отводится под путь к файлу, а второй – под номер строки в файле. Также необходимо учитывать, что стандартно первая строка файла интерпретируется как строка заголовков таблицы. Бывают случаи, когда в первой строки вместо заголовков, содержатся данные и их необходимо обработать. Для того, чтобы первая строка интерпретировалась как строка данных, необходимо:

InputFormat.headerRow = FALSE

На примере формата CSV, с отключением строки заголовков, столбцы именуются следующим образом:

• Filename
• RowNumber
• Field1
• Field2
• …

Когда все настройки произведены, можно производить чтение набора данных:

RecordSet = LogQuery.Execute(SQL; InputFormat)

Данные получены и содержатся в RecordSet. Следующим шагом к обработке будет чтение записи, которое осуществляется методом getRecord():

Record = RecordSet.getRecord()

Для получения значений полей записи воспользуемся следующим методом:

Record.getValue(Название_столбца)

Для осуществления передвижения по записям внутри RecordSet применяются методы moveNext(), а для проверки окончания – метод atEnd().

В результате, все записи можно обработать следующим циклом:

  PATH = 'D:\Table1.csv'
  LogQuery = CreateObject('MSUtil.LogQuery')
  InputFormat = CreateObject('MSUtil.LogQuery.CSVInputFormat')
  InputFormat.headerRow = FALSE
  SQL = Format('SELECT * FROM %s'; PATH)
  RecordSet = LogQuery.Execute(SQL; InputFormat)
  COLUMN_COUNT = RecordSet.getColumnCount()
  while not RecordSet.atEnd()
    Record = RecordSet.getRecord()
    i = 1
    while i < COLUMN_COUNT - 2
      FIELD = Record.getValue(Format('Field%d'; i))
      if not VarIsNull(FIELD)
        //Операторы обработки
        //...
      endif
      i = i + 1
    endwhile
    RecordSet.moveNext()
  endwhile

Пример

Предположим, нам необходимо обработать файл D:\Test.csv, содержащий следующие строки:

Date,Description
10/23/2013,'Test 1'
10/24/2013,'Test 2'
10/25/2013,'Test 3'

Как видно, входной файл имеет формат CSV, а первая строка содержит заголовки. Поэтому алгоритм обработки данного файла будет иметь следующий вид:

  CSV_PATH = 'D:\Test.csv' 
  LogQuery = CreateObject('MSUtil.LogQuery')
  CSVInputFormat = CreateObject('MSUtil.LogQuery.CSVInputFormat')
  SQL = Format('SELECT * FROM %s'; CSV_PATH)
  RecordSet = LogQuery.Execute(SQL; CSVInputFormat)
  COLUMN_COUNT = RecordSet.getColumnCount()
  StrList = CreateStringList()
  while not RecordSet.atEnd()
    Record = RecordSet.getRecord()
    Date = Record.getValue('Date')
    Description = Record.getValue('Description')
    StrList.Add(Date & TAB & Description)
    RecordSet.moveNext()
  endwhile
  EditText(StrList.Text)

Результатом работы данного алгоритма будет окно EditText:

Итоги

В данной статье были рассмотрены основные возможности парсинга файлов при помощи утилиты Log Parser компании Microsoft посредством COM-модели.

Алгоритм работы с Log Parser посредством COM-модели следующий:

1. Создать COM-объект LogQuery.
2. Создать входной формат.
3. Создать SQL запрос.
4. Считать все данные в RecordSet.
5. Производить последовательное чтение записей из RecordSet в Record.