Как поставить штамп с информацией о ЭП на документ

Сталкивались на предприятии с ситуацией, когда бухгалтерия на распечатанный, подписанный ЭП документ требует поставить живую подпись? «Как же так?!» - возмущаются пользователи - «Есть же электронная подпись». А в бухгалтерии все равно нужно подтверждение, что документ подписан. И желательно, чтобы «вот прямо» на распечатанном документе. Как в банке проставляют штамп «Исполнено» на платежках:

Давайте обсудим, как это можно сделать в DIRECTUM.

В системе DIRECTUM есть функции, позволяющие проставлять штамп, содержащий определенный текст, в документ. Необходимо учесть, что в документе могут быть как подписанные версии, так и не подписанные. Причем подписанных версий может быть несколько. Важным условием также является требование неизменности документа после простановки на него штампа.

Исходя из всего перечисленного можно выработать следующий алгоритм:

1. Определяем, подписан ли вообще документ.
2. Ищем последнюю подписанную версию.
3. Формируем изображение штампа с текстом, содержащим информацию о подписях.

Примерно, вот так:

4. Экспортируем последнюю подписанную версию документа.
5. Преобразовываем выгруженный документ в формат pdf.
6. Проставляем на него штамп.
7. Импортируем pdf-документ со штампом в новую версию электронного документа.
8. Распечатываем документ.

Данный функционал можно навесить на специальную кнопку на ТКЭД, можно создать отдельный расчет с возможностью выбора документа. Это уже на усмотрение пользователей и программистов системы.

Предложенный алгоритм был реализован в виде прикладной функции DIRECTUM на версии 5.2. Напомню, что функции по установке штампов на pdf-документах появились в версии 5.0.

Итак, код функции:

  //Делаем проверку парметра функции EDocument. EDocument – переданный в функцию документ, преобразование которого необходимо выполнить
  // Не указан параметр "%s".
  Assert(Assigned(EDocument); LoadStringFmt('DIRE434A6BC_59D8_4AF4_A58D_5105D7C60DF6'; 'COMMON'; 'EDocument'))
//Блокируем документ от изменения
  EDocument.Lock
  EMPTY_STR = ''
  NOT_FOUND = -1
  PDF = 'PDF'
  
  // Тип документа по расширению
  Extension = EDocument.Info.Editor.Extension
  
  // Если уже PDF, подтвердить постановку штампов  
  if Extension == PDF
    YES = 'Да'
    NO = 'Нет'
    Answer = MessageBox(ATTENTION_CAPTION; 'У данного документа уже есть версия в формате PDF^Создать новую версию документа со штампами на основе последней действующей подписанной версии?'; YES & "|" & NO; NO; NO)
    if Answer == NO
      EDocument.UnLock
      Exit()
    endif
  endif
  // Найти номер последней действующей подписанной версии
  LastVersionNumber = NOT_FOUND
  Versions = EDocument.Versions
  Index = 0
  while Index < Versions.Count
    Version = Versions.Values(Index)
    if Version.CurrentState = vsActive and Version.Signed
      LastVersionNumber = Version.Number
      Extension = Version.Editor.Extension
    endif
    Index = Index + 1
  endwhile
  
  if LastVersionNumber = NOT_FOUND
    EDocument.UnLock
    Raise(CreateException("ENoActiveVersionFound"; "У документа нет ни одной действующей подписанной версии"; ecWarning))
  endif

  // Экспортировать последнюю подписанную версию
  ExportFile = Format("%s%s.%s"; ArrayOf(GetTempFolder(); EDocument.ID; Extension))
  DeleteFile(ExportFile)
  EDocument.Export(LastVersionNumber; ExportFile; false; false; false)

  try 
   // Преобразовать в PDF, если экспортировали версию, которая не являлась pdf-документом.
   if Extension <<>> 'PDF'
      WSDLFileName = GetConstant('DCTSConvertToPDFWSDL')
      PDFFile = Format("%s%s.pdf"; ArrayOf(GetTempFolder(); EDocument.ID))
      DeleteFile(PDFFile)
      DCTSConvertFileToPDF(WSDLFileName; ExportFile; PDFFile)
    else
      PDFFile = ExportFile
    endif      
    // Общие параметры штампов
    StampFilename = GetTempFolder() & "stamp.png"
    STAMP_COLOR = '000000' // Черный
    STAMP_FONT_FACE = 6 // Times New Roman
    STAMP_FONT_SIZE = 20
  
    // ШТАМП С ДАННЫМИ ЭЦП ДОКУМЕНТА
    SignatureField        = EMPTY_STR // Часть штампа с информацией об ЭЦП
    SignatureDate         = EMPTY_STR
    SerialNumber          = EMPTY_STR
    CertificateValidFrom  = EMPTY_STR
    CertificateValidTo    = EMPTY_STR
    SubjectName           = EMPTY_STR
    SignatureAuthor       = EMPTY_STR
    // Собрать информацию о параметрах ЭП
    SignatureFieldStringList =  CreateStringList()
    Signatures = EDocument.Versions.Values(LastVersionNumber-1).Signatures
    if Signatures.Count > 0
      SignatureIndex = Signatures.Count - 1
      while SignatureIndex >= 0
        Signature = Signatures.Values(SignatureIndex)
          //Найти утверждающую подпись
          if Signature.SignatureType <> stNone 
            AuthorUser = Signature.Author
            Certificate   = Signature.Certificate            
            SerialNumber = Certificate.SerialNumber
            if Assigned(AuthorUser) and SerialNumber <<>> EMPTY_STR
              SignatureAuthor = AuthorUser.FullName
              SignatureType = IfThen(Signature.SignatureType = stApproving; 'утверждающая ЭП'; 'визирующая ЭП') 
              CertificateValidFrom = FormatDate('D.M.YY'; Certificate.ValidFromDate)
              CertificateValidTo = FormatDate('D.M.YY'; Certificate.ValidToDate)
              SignatureDate = FormatDate('D.M.YY'; Signature.Date)
              ValidText = IfThen(Signature.IsValid; 'ЭП достоверна'; 'ЭП не достоверна')
              SignatureField = Format("Подписан ЭП: %s   Серт.: %s, действ. %s - %s, тип: %s, достоверность: %s";
                                      ArrayOf(SignatureAuthor;
                                              SerialNumber;
                                              CertificateValidFrom;
                                              CertificateValidTo;
                                              SignatureType;
                                              ValidText))
              SignatureFieldStringList.Add(SignatureField)
            endif
          endif
        SignatureIndex = SignatureIndex - 1
      endwhile
      
    // Сегодня ДД.ММ.ГГГГ
      CurrentDate = FormatDate('D.M.YY'; Today())
      SignatureFieldStringList.Delimiter = CR
      StampText = CurrentDate & ', ' & SignatureFieldStringList.DelimitedText
      // Рамка штампа
      STAMP_BORDER = 1
      STAMP_BORDER_THICKNESS = 8
      // Сгенерировать изображение с текстом, содержащим информацию о параметрах ЭП 
      GenerateTextImage(StampText; STAMP_BORDER; STAMP_BORDER_THICKNESS; STAMP_COLOR; STAMP_FONT_SIZE; STAMP_FONT_FACE; StampFilename; 0)
    
      // Добавить штамп в PDF-документ
      STAMP_SCALE = 30

      PagesMode = 2

      AddImageToPDFFile(PDFFile; StampFilename;;; PagesMode; nil; STAMP_SCALE) 
      EDocument.UnLock
      // Импортировать документ в новую версию электронного документа
      EDocument.ImportFromFile(-1; 'Версия со штампами ЭЦП в PDF на основе последней подписанной'; PDFFile)
      OpenFile(PDFFile)
    endif
  except
    EDocument.UnLock
  endexcept  

В результате работы данного функционала в электронном документе появится версия, содержимое которой неизменно и которая содержит штамп с информацией о ЭП, поставленных на документе.